#  OpenBUGS CODE FOR THE LEWIS ET AL PAPER
#  WEIBULL TIME-TO-EVENT MODEL WITH COMENSURATE PRIOR

#  N1 = # of historical controls
#  N2 = # of concurrent controls
#  N3 = # of concurrent treateds

model{	
	for(i in 1 : N1) {  
         t[i] ~ dweib(r, mu[i])C(t.cen[i],)      
	    mu[i]<- exp(beta[1]+gamma*(x[i]- mean(x[])))
	    median[i] <- pow(log(2) * exp(-(beta[1]+gamma*(x[i]- mean(x[])))), 1/r)
			}
	for(i in (N1+1): (N2+N1)) {
		t[i] ~ dweib(r, mu[i])C(t.cen[i],)      
		mu[i]<- exp(beta[2]+gamma*(x[i]- mean(x[])))
		median[i] <- pow(log(2) * exp(-(beta[2]+gamma*(x[i]- mean(x[])))), 1/r)
		}
	for(i in (N1+N2+1):(N1+N2+N3)) {
		t[i] ~ dweib(r, mu[i])C(t.cen[i],)      
		mu[i] <- exp(beta[3]+gamma*(x[i]- mean(x[])))
		median[i] <- pow(log(2) * exp(-(beta[3]+gamma*(x[i]- mean(x[])))), 1/r)
			}
        gamma ~ dnorm(0,0.001)
	beta[1] ~ dnorm(0.0, 0.001)
	beta[3] ~ dnorm(0.0, 0.001)
	beta[2] ~ dnorm(beta[1], tau)  #  This is the commensurate prior; (hyper)priors on the commensurability parameter follow:
	
#	tau ~ dgamma(1, 0.001)  #  original prior;  EHSS = 0
#	tau ~ dgamma(10, 1)       #  tight prior near 10;  EHSS = 55.27
#	tau ~ dgamma(10, 0.01)  #  less vague prior near 1000;  EHSS = 199.07
 	tau ~ dgamma(10, 0.1)     #  moderate prior near 100;  EHSS = 37.30, or 42.85
#      tau ~ dgamma(1000, 1)     #  supertight prior near 1000;  EHSS = 243 -- very close!
			
		    r ~ dexp(0.1)
		    trt.cc <- beta[3] - beta[2]  
		    trt.hc <- beta[3] - beta[1]
		    cc.hc <- beta[2] - beta[1] 
		
	}  # END OF BUGS CODE
	
#  HERE ARE INITS :
	
list(beta=c(-1, -1, -1), gamma=0.1, r = 10)
list(beta=c(0,0,0), gamma=0 , r = 2)
list(beta=c(1,1,1), gamma=-0.1 , r = 1)